blob: 5090cc1a239402629c65c940b911b24f4a389fb7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Max Weber <abex at runelite dot net>
# Contributor: Jason Stryker <public at jasonstryker dot com>
pkgname=runelite-git
pkgver=1.12.13.r4.g02e33cb
pkgrel=1
pkgdesc="Open source Old School RuneScape client. (Git Version)"
url='https://runelite.net/'
arch=(any)
license=('BSD')
depends=(
'java-runtime>=11'
'ttf-font')
optdepends=(
'gvfs: enable links'
'libnotify: native tray notifications')
makedepends=(
'git')
provides=("runelite=${pkgver}")
conflicts=('runelite')
source=(
"git+https://github.com/runelite/runelite.git"
runelite.desktop
runelite.png)
sha512sums=(
'SKIP'
'SKIP'
'SKIP')
pkgver() {
cd "${srcdir}/runelite"
git describe --long --abbrev=7 | sed 's/runelite-parent-//g;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${srcdir}/runelite/"
./gradlew :client:clean :client:shadowJar --no-daemon
}
package() {
_client_jar="$(find "${srcdir}/runelite/runelite-client/build/libs/" -type f -name 'client-*-shaded.jar')"
install -D -m644 \
"$_client_jar" \
"${pkgdir}/usr/share/java/runelite/RuneLite.jar"
install -D -m644 \
"${srcdir}/runelite.desktop" \
"${pkgdir}/usr/share/applications/runelite.desktop"
install -D -m644 \
"${srcdir}/runelite.png" \
"${pkgdir}/usr/share/pixmaps/runelite.png"
install -D -m644 \
"${srcdir}/runelite/LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -D -m755 \
"/dev/null" \
"${pkgdir}/usr/bin/runelite"
echo '#!/bin/sh' > "${pkgdir}/usr/bin/runelite"
echo 'exec java -jar /usr/share/java/runelite/RuneLite.jar "$@"' >> "${pkgdir}/usr/bin/runelite"
}
|