PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Meir Kriheli <mkriheli@gmail.com>
pkgname=rusmux
pkgver=0.8.5
pkgrel=1
pkgdesc="tmux automation tool"
arch=("x86_64")
url="https://github.com/MeirKriheli/rusmux"
license=("MIT")
makedepends=("cargo")
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('d26685684e1f36c3aeb00f174c676f09ff9a9051149fdf424f9261dba4b672b3')

prepare() {
  cd "$pkgname-$pkgver"
  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
  cd "$pkgname-$pkgver"
  cargo build --release --frozen
}

check() {
  cd "$pkgname-$pkgver"
  cargo test --frozen
}

package() {
  cd "$pkgname-$pkgver"
  install -Dm 0755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  install -Dm 0644 "man/rusmux.1" "$pkgdir/usr/share/man/man1/rusmux.1.gz" -Z
  install -Dm 0644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  install -Dm 0644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  install -Dm 0644 "completions/rusmux.zsh" "${pkgdir}/usr/share/zsh/site-functions/_rusmux"
  install -Dm 0644 "completions/rusmux.bash" "${pkgdir}/usr/share/bash-completion/completions/rusmux"
  install -Dm 0644 "completions/rusmux.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/rusmux.fish"
}