blob: 81e33431c7c76b62203d3ac01f04cb610c2debae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: KUHTOXO https://aur.archlinux.org/account/kuhtoxo
# Maintainer: Zoddo <archlinux+aur@zoddo.fr>
# Contributor: void09 <sgmihai at gmail dot com>
# Contributor: taotieren <admin@taotieren.com>
# Contributor: Leon Möller <jkhsjdhjs at totally dot rip>
pkgbase=rustdesk-bin
pkgname=(rustdesk-bin)
pkgver=1.3.7
pkgrel=1
pkgdesc="Yet another remote desktop software, written in Rust. Works out of the box, no configuration required."
url="https://github.com/rustdesk/rustdesk"
license=('AGPL-3.0-only')
arch=('x86_64' 'aarch64')
provides=("${pkgname%-bin}")
conflicts=("${pkgname%-bin}")
depends=(
'gtk3'
'xdotool'
'libxcb'
'libxfixes'
'alsa-lib'
'libva'
'libvdpau'
'pam'
'gst-plugins-base'
'gst-plugin-pipewire'
)
optdepends=(
'libappindicator-gtk3: tray icon'
'libayatana-appindicator: tray icon'
)
options=('!strip' '!lto' '!debug')
source_x86_64=("${pkgbase%-bin}-${pkgver}-x86_64.pkg.tar.zst::$url/releases/download/${pkgver/_/-}/rustdesk-${pkgver/_/-}-0-x86_64.pkg.tar.zst")
source_aarch64=("${pkgbase%-bin}-${pkgver}-aarch64.rpm::$url/releases/download/${pkgver/_/-}/rustdesk-${pkgver/_/-}-0.aarch64.rpm")
sha256sums_x86_64=('fff2defb0bd41c8bf546d5fb77355519be67ab38a410126aa9cf6e3dcc83c756')
sha256sums_aarch64=('cbd98c7b748fda4739ef4fd3eaad33621de7909508787c03931a42e3dbce12d6')
install=$pkgname.install
package() {
install -d "${pkgdir}/usr/share/" "${pkgdir}/usr/bin/"
cp -r "${srcdir}/usr/share/rustdesk/" "${pkgdir}/usr/share/"
cp -r "${srcdir}/usr/share/icons/" "${pkgdir}/usr/share/"
ln -s "/usr/share/rustdesk/rustdesk" "${pkgdir}/usr/bin/rustdesk"
install -Dm 644 "${srcdir}/usr/share/rustdesk/files/rustdesk.service" "${pkgdir}/usr/lib/systemd/system/rustdesk.service"
install -Dm 644 "${srcdir}/usr/share/rustdesk/files/rustdesk.desktop" "${pkgdir}/usr/share/applications/rustdesk.desktop"
install -Dm 644 "${srcdir}/usr/share/rustdesk/files/rustdesk-link.desktop" "${pkgdir}/usr/share/applications/rustdesk-link.desktop"
# Remove useless files
rm -r "${pkgdir}/usr/share/rustdesk/files/"
}
|