blob: c5a641d16be661c5936d37335c3d5035d163d189 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Maintainer: weilinfox <sakurakaze.fox at gmail.com>
pkgname=ruyi
pkgver=0.54.0
pkgrel=1
pkgdesc="RuyiSDK Package Manager"
arch=(any)
url="https://github.com/ruyisdk/ruyi"
license=(Apache-2.0)
depends=(
'python>=3.11'
'python-argcomplete'
'python-arpy'
'python-babel'
'python-certifi'
'python-fastjsonschema'
'python-jinja'
'python-lz4'
'python-packaging'
'python-pathspec'
'python-pyelftools'
'python-pygit2'
'python-requests'
'python-rich'
'python-semver'
'python-tomlkit'
'python-typing_extensions'
'python-yaml'
'python-zstandard'
)
makedepends=(
'python-build'
'python-installer'
'python-poetry-core'
)
checkdepends=(
'python-pytest'
'unzip'
)
optdepends=(
'android-tools: fastboot support'
'bash: ruyi use bash as default shell'
'bzip2: bzip file support'
'curl: curl downloading support'
'coreutils: dd support'
'gzip: gunzip file support'
'sudo: privileged operations support'
'tar: untar tarball support'
'unzip: zip file support'
'wget: wget downloading support'
'xz: xz file support'
'zstd: zstd file support'
)
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/ruyisdk/ruyi/archive/refs/tags/${pkgver}.tar.gz"
"config.toml"
"ruyi-completion"
)
sha512sums=('1ec984010a2248ccf3ecd7cd6463fc6c1751c949b373b5111b1d54bf01ca8eeed1c6b3634b53edfdce0b9cd83733b9ec62a5e2ff9440461078c30ad7ce038944'
'03b9a18c495c37203e5c56518e1ab94118b3bf99e83c99924f3eeca7be64ac3b03d744c105ac99ab703c40e570195a7ed39785e5beef5f619bdf868bd6add6f6'
'8fb7bdd45b70ee740fcf279037a62463e13da589221bb52793a074e4063bf8b7d306fef0879980a1be893d76a0536c4ab6b124aec576b96372a8898f5307d609')
provides=(python-ruyi)
build() {
cd "$pkgname-$pkgver"
python -m build --wheel --skip-dependency-check --no-isolation
}
check() {
cd "$pkgname-$pkgver"
python -m pytest -v --ignore tests/pluginhost/test_api.py
}
package() {
cd "$pkgname-$pkgver"
python -m installer -d "$pkgdir" dist/*.whl
install -Dm644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}/"
install -Dm644 LICENSE*.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 ../config.toml -t "${pkgdir}/usr/share/${pkgname}/"
install -Dm644 ../ruyi-completion "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
}
|