blob: 01f815b5b9b9a443e4305fe2718df6d5c480f536 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: k1f0 <generic at k1f0.mozmail.com>
pkgname=rwpspread
pkgver=0.5.1
pkgrel=1
_patch=""
pkgdesc='Multi-Monitor Wallpaper Utility'
arch=('x86_64' 'aarch64')
url='https://github.com/0xk1f0/rwpspread'
license=('GPL-3.0-only')
makedepends=('cargo' 'git' 'gzip')
optdepends=('wpaperd: wallpaper setter backend'
'swaybg: wallpaper setter backend'
'hyprpaper: wallpaper setter backend')
provides=("${pkgname}")
conflicts=("${pkgname}-git")
source=("${pkgname}-${pkgver}${_patch}::git+${url}.git#tag=v${pkgver}")
sha256sums=('890c493d49f66763fd38076875d8f4e830136611bfc57cf33221f99606dec444')
options=(!debug)
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}${_patch}"
cargo fetch --locked --target "${CARCH}-unknown-linux-gnu"
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}${_patch}"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}${_patch}"
# binary
install -Dm0755 -t "${pkgdir}/usr/bin" "target/release/${pkgname}"
# shell completions
mv "target/release/completions/${pkgname%-git}.bash" "target/release/completions/${pkgname%-git}"
install -Dm0644 -t "${pkgdir}/usr/share/bash-completion/completions" "target/release/completions/${pkgname%-git}"
install -Dm0644 -t "${pkgdir}/usr/share/zsh/site-functions" "target/release/completions/_${pkgname%-git}"
install -Dm0644 -t "${pkgdir}/usr/share/fish/vendor_completions.d" "target/release/completions/${pkgname%-git}.fish"
# man page
gzip "target/release/man/${pkgname%-git}.1"
install -Dm0644 -t "${pkgdir}/usr/share/man/man1" "target/release/man/${pkgname%-git}.1.gz"
# license
install -Dm0644 -t "${pkgdir}/usr/share/licenses/${pkgname%-git}" "LICENSE"
}
|