blob: bdc2576af870faa0de971ccb23efe305e3878589 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Maintainer: Dan Elkouby <streetwalrus@codewalr.us>
_pkgname=rxvt-unicode
pkgname=rxvt-unicode-intensityfix
pkgver=9.22
pkgrel=11
pkgdesc='A unicode enabled rxvt-clone terminal emulator (urxvt), with various fixes'
arch=('i686' 'x86_64')
url='http://software.schmorp.de/pkg/rxvt-unicode.html'
license=('GPL')
depends=('libxft' 'perl' 'startup-notification' 'gdk-pixbuf2')
provides=('rxvt-unicode' 'rxvt-unicode-terminfo')
conflicts=('rxvt-unicode' 'rxvt-unicode-terminfo')
source=(
"http://dist.schmorp.de/rxvt-unicode/$_pkgname-$pkgver.tar.bz2"
'intensity.patch'
'background-img-use-color.patch'
'font-width-fix.patch'
'line-spacing-fix.patch'
'https://gist.githubusercontent.com/alexoj/df5bae7a4825cb596581/raw/75a1e75c2ae1ec5c0db68a29f8a6821e9e3d87a5/sgr-mouse-mode.patch'
'256color.patch'
)
md5sums=('93782dec27494eb079467dacf6e48185'
'9e2ccfa07aafa6aeaf1dbdd005437af7'
'd8377a6ec47a7913636fbc368aded94b'
'fef588d6bfe52304bf80e8f1771577b6'
'9f3248bc397ee76b008375f2ab0f201a'
'f8325b0a33999db4d5d1eeac4f320156'
'fb78c2ecf87626962734320cc2bb7ab1')
prepare() {
cd $_pkgname-$pkgver
patch -p0 -i ../intensity.patch
patch -p0 -i ../background-img-use-color.patch
# From https://aur.archlinux.org/packages/rxvt-unicode-patched/
patch -p0 -i ../font-width-fix.patch
patch -p0 -i ../line-spacing-fix.patch
patch -p0 -i ../sgr-mouse-mode.patch
# From https://aur.archlinux.org/packages/rxvt-unicode-256xresources/
patch -p0 -i ../256color.patch
}
build() {
cd $_pkgname-$pkgver
# we disable smart-resize (FS#34807)
# do not specify --with-terminfo (FS#46424)
./configure \
--prefix=/usr \
--enable-256-color \
--enable-combining \
--disable-fading \
--enable-font-styles \
--disable-iso14755 \
--disable-keepscrolling \
--enable-lastlog \
--enable-mousewheel \
--disable-next-scroll \
--enable-perl \
--enable-pointer-blank \
--disable-rxvt-scroll \
--enable-selectionscrolling \
--disable-slipwheeling \
--disable-smart-resize \
--enable-startup-notification \
--disable-transparency \
--enable-unicode3 \
--enable-utmp \
--enable-wtmp \
--enable-xft \
--disable-xim \
--disable-xterm-scroll \
--enable-pixbuf \
--enable-frills
make
}
package() {
# install terminfo
cd $_pkgname-$pkgver
export TERMINFO="$pkgdir/usr/share/terminfo"
install -dm 755 "$TERMINFO"
make DESTDIR="$pkgdir" install
rm -f "$pkgdir"/usr/bin/urxvt{c,d}
}
# vim:set ts=2 sw=2 et:
|