blob: 43e8e5e28b3d37d191e9a9b62df5d59bd9443db2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer: zer0def <zer0def@github>
# Contributor: Kirill Goncharov <kdgoncharov cat gmail dog com>
# Contributor: Johannes Löthberg <johannes@kyriasis.com>
# Contributor: Sébastien Luttringer
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Christer Edwards <christer.edwards@gmail.com>
pkgname=salt-py3
pkgver=2019.2.3
pkgrel=3
pkgdesc='Central system and configuration manager'
arch=('any')
url='http://saltstack.org/'
license=('Apache')
provides=('salt')
replaces=('salt' 'salt-zmq' 'salt-raet')
conflicts=('salt' 'salt-zmq' 'salt-raet')
depends=('python-jinja'
'python-msgpack'
'python-yaml'
'python-markupsafe'
'python-requests'
'python-pyzmq'
'python-crypto'
'python-m2crypto'
'python-systemd'
'python-tornado5')
optdepends=('dmidecode: decode SMBIOS/DMI tables'
'python-pygit2: gitfs support')
backup=('etc/logrotate.d/salt'
'etc/salt/master'
'etc/salt/minion')
install=salt.install
source=("https://pypi.io/packages/source/s/salt/salt-$pkgver.tar.gz"
"salt.logrotate"
"0001-saltssh-py38.patch")
sha256sums=('7497e7dbfd4dc3799bbbc8da63da98b8301bbb644150f3905fe5775a7d81271a'
'abecc3c1be124c4afffaaeb3ba32b60dfee8ba6dc32189edfa2ad154ecb7a215'
'8029d67585bab0b0858c3e2fb317b08bfbeee94d8c785c74472e9c9ecd4c0d3c')
prepare() {
cd salt-$pkgver
patch -p1 < ../0001-saltssh-py38.patch
}
build() {
cd salt-$pkgver
python setup.py build
}
package() {
install -Dm644 salt.logrotate "$pkgdir"/etc/logrotate.d/salt
cd salt-$pkgver
python setup.py --salt-pidfile-dir="/run/salt" install --root="$pkgdir" --optimize=1 --skip-build
# default config
install -Dm644 conf/master "$pkgdir/etc/salt/master"
install -Dm644 conf/minion "$pkgdir/etc/salt/minion"
# systemd services
for _svc in salt-master.service salt-syndic.service salt-minion.service salt-api.service; do
install -Dm644 pkg/$_svc "$pkgdir/usr/lib/systemd/system/$_svc"
done
install -Dm644 pkg/salt.bash "$pkgdir/usr/share/bash-completion/completions/salt"
install -Dm644 pkg/zsh_completion.zsh "$pkgdir/usr/share/zsh/site-functions/_salt"
}
# vim:set ts=2 sw=2 et:
|