PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Maintainer: George Rawlinson <grawlinson@archlinux.org>

pkgbase=samplebrain
pkgname=('samplebrain' 'samplebrain-docs')
pkgver=0.18.4
pkgrel=1
pkgdesc='Custom sample smashing app designed by Aphex Twin'
arch=('x86_64')
url='https://gitlab.com/then-try-this/samplebrain'
license=('GPL2')
makedepends=(
  'git'
  'hicolor-icon-theme'
  'libsndfile'
  'portaudio'
  'liblo'
  'fftw'
  'qt5-base'
)
_commit='ac83efce3b53c0ae6ca6723602d168b88b8ecb9e'
source=("$pkgbase::git+$url.git#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd "$pkgbase"

  git describe --tags | sed 's/_release//'
}

build() {
  cd "$pkgbase"

  qmake-qt5

  make
}

package_samplebrain() {
  depends=(
    'hicolor-icon-theme'
    'libsndfile'
    'portaudio'
    'liblo'
    'fftw'
    'qt5-base'
  )
  optdepends=('samplebrain-docs: documentation')

  cd "$pkgbase"

  make INSTALL_ROOT="$pkgdir" install
}

package_samplebrain-docs() {
  pkgdesc+=' (documentation)'

  cd "$pkgbase"

  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgbase" README.md
  cp -vr docs "$pkgdir/usr/share/doc/$pkgbase"
}