blob: 858ab3bbe4612415a9d5af4df6ea28bb27f22fae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Milk Brewster <milk on freenode>
# Contributor: Christopher Arndt <aur -at- chrisarndt -dot- de>
_pkgname="samplecat"
pkgname="${_pkgname}-git"
pkgver=0.3.1.r15.g5e26576
pkgrel=1
pkgdesc="A program for cataloguing and auditioning audio samples."
arch=(x86_64)
url="http://ayyi.github.io/samplecat"
license=('GPL')
depends=(
'dbus-glib'
'ffmpeg'
'fftw'
'graphene'
'gtk2'
'jack'
'libsndfile'
'libyaml'
'mariadb-libs'
'sqlite'
)
makedepends=(
'git'
'ladspa'
'python'
)
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=('git+https://github.com/ayyi/samplecat.git'
'git+https://github.com/ayyi/libwaveform.git'
"libwaveform-peak-tempfiles.diff")
md5sums=('SKIP'
'SKIP'
'824d2703d40b2256253b14185171f6f6')
pkgver() {
cd "$srcdir/${_pkgname}"
( set -o pipefail
git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
prepare() {
cd "$srcdir/${_pkgname}"
git submodule init
git config submodule.waveform.url "${srcdir}/libwaveform"
git submodule update
# https://github.com/ayyi/libwaveform/pull/7
cd lib/waveform
patch -p1 -N -r - -i "${srcdir}"/libwaveform-peak-tempfiles.diff || :
}
build() {
cd "$srcdir/${_pkgname}"
./autogen.sh
./configure --prefix=/usr
make
}
package() {
cd "$srcdir/${_pkgname}"
make DESTDIR="$pkgdir/" install
# Layout files not used (yet)?
rm -rf "$pkgdir"/usr/etc
}
|