blob: 9a3bf7115ef11949c09ebdc8fb5f883f930decef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: telans <telans@protonmail.com>
# Co-Maintainer: Simon Tas <simon.tas.st@gmail.com>
pkgname="samrewritten-git"
_pkgname="SamRewritten"
pkgver=r135.cbc9583
pkgrel=1
pkgdesc="A Steam Achievement Manager For Linux."
arch=("any")
url="https://github.com/PaulCombal/SamRewritten"
license=("GPL3")
depends=("steam" "yajl" "gtkmm3" "glibc" "curl")
optdepends=("zenity: error messages with style"
"valgrind: for automated dev script"
"massif-visualizer: for automated dev script")
makedepends=("git" "make" "gcc>=9.0")
source=("git+https://github.com/PaulCombal/SamRewritten.git")
sha256sums=("SKIP")
pkgver() {
cd ${_pkgname}
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd ${_pkgname}
make
}
package() {
install -dm755 "${pkgdir}/usr/lib/"
# Only copy required files. (Except for Glade files, as more may be added in the future.)
cp -r --parents ${_pkgname}/{LICENSE,README.MD,bin/{launch.sh,libsteam_api.so,samrewritten},glade/*.glade,assets/icon_256.png} ${pkgdir}/usr/lib/
install -Dm644 ${_pkgname}/assets/icon_256.png ${pkgdir}/usr/share/icons/hicolor/256x256/apps/samrewritten.png
install -Dm644 ${_pkgname}/assets/icon_64.png ${pkgdir}/usr/share/icons/hicolor/64x64/apps/samrewritten.png
# Executable
install -dm755 ${pkgdir}/usr/bin
ln -s /usr/lib/${_pkgname}/bin/launch.sh ${pkgdir}/usr/bin/samrewritten
# Desktop Entry
install -Dm644 ${_pkgname}/package/samrewritten.desktop ${pkgdir}/usr/share/applications/samrewritten.desktop
}
|