blob: a068798f4adb999f8176bef9da15228b2f69e4d5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: r6eve <r6eve at acm dot org>
# Former Maintainer (thnaks!): Christopher Vittal ("viralstitch") <chris@vittal.dev>
# Former Maintainer (thans!) : Alex Peltzer ("alexpe87") <alexpe.aur@mailbox.org>
# Former Maintainer (thanks dude!) : Christian Krause ("wookietreiber") <christian.krause@mailbox.org>
# Contributor: Markus Heuser <markus.heuser@web.de>
pkgname=samtools
pkgver=1.14
pkgrel=1
pkgdesc="tools for manipulating next-generation sequencing data"
arch=('i686' 'x86_64')
url="http://www.htslib.org/"
license=('custom')
depends=('htslib>=1.14')
optdepends=('luajit: needed for r2plot.lua vcfutils.lua')
source=("${pkgname}-${pkgver}.tar.bz2"::"https://github.com/samtools/samtools/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.bz2")
sha256sums=('9341dabaa98b0ea7d60fd47e42af25df43a7d3d64d8e654cdf852974546b7d74')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
# prevent shipped htslib to be used
rm -rf "htslib-${pkgver}" || exit 1
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--with-htslib=system
make
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make check
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
# Install non-Perl misc/ programs
for file in misc/*.lua; do
install -Dm755 "${file}" "${pkgdir}/usr/bin/$(basename "${file}")"
done
install -d "${pkgdir}/usr/include/bam"
install -Dm644 *.h "${pkgdir}/usr/include/bam"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|