blob: fa4ffa9bf7e7338034e588f8dd2f942f15b806b9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=samtools-git
pkgver=1.10.r98.gfaab8b0
pkgrel=1
pkgdesc="Tools for manipulating next-generation sequencing data"
arch=('i686' 'x86_64')
url="https://www.htslib.org/"
license=('MIT')
depends=('glibc' 'htslib' 'ncurses' 'zlib')
makedepends=('git')
provides=('samtools')
conflicts=('samtools')
source=("git+https://github.com/samtools/samtools.git")
sha256sums=('SKIP')
pkgver() {
cd "samtools"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "samtools"
autoreconf -fi
./configure \
--prefix="/usr" \
--with-htslib=system
make
}
check() {
cd "samtools"
#make check
}
package() {
cd "samtools"
make DESTDIR="$pkgdir" install
install -Dm755 "misc"/*.lua -t "$pkgdir/usr/bin"
install -Dm644 *.h -t "$pkgdir/usr/include/bam"
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/samtools"
}
|