blob: 34e5b989c06493970c64732f7eeda1625c164b9e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
pkgname=sanoid-git
pkgver=r926.dbcaeef
pkgrel=1
pkgdesc="Policy-driven snapshot management (sanoid), dataset sending/receiving (syncoid) and snapshot searching (findoid) tools for ZFS."
arch=('any')
url='https://github.com/jimsalterjrs/sanoid'
license=('GPL3')
backup=('etc/sanoid/sanoid.conf')
depends=(
'perl-capture-tiny'
'perl-config-inifiles'
)
optdepends=(
'pv: progress bars'
'mbuffer: stream buffering'
'gzip: compression'
'pigz: compression'
'zstd: compression'
'lz4: compression'
'xz: compression'
'lzop: compression'
'busybox: insecure direct connection'
)
makedepends=('git')
conflicts=('sanoid')
provides=('sanoid')
source=("sanoid-git::git+https://github.com/jimsalterjrs/sanoid.git")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
# Change /usr/sbin to /usr/bin
cd "${pkgname}"
sed -i 's|/usr/sbin|/usr/bin|g' \
"packages/debian/sanoid.timer" \
"packages/debian/sanoid.service" \
"packages/debian/sanoid.sanoid-prune.service"
}
package() {
cd "${pkgname}"
# Documents
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/sanoid/LICENSE"
install -Dm644 README.md "${pkgdir}/usr/share/doc/sanoid/README.md"
# Configs
install -Dm644 sanoid.conf "${pkgdir}/etc/sanoid/sanoid.conf"
install -Dm644 sanoid.defaults.conf "${pkgdir}/etc/sanoid/sanoid.defaults.conf"
# Binaries
install -Dm755 sanoid "${pkgdir}/usr/bin/sanoid"
install -Dm755 syncoid "${pkgdir}/usr/bin/syncoid"
install -Dm755 findoid "${pkgdir}/usr/bin/findoid"
# systemd
install -D -m 644 "packages/debian/sanoid.timer" "${pkgdir}/usr/lib/systemd/system/sanoid.timer"
install -D -m 644 "packages/debian/sanoid.service" "${pkgdir}/usr/lib/systemd/system/sanoid.service"
install -D -m 644 "packages/debian/sanoid.sanoid-prune.service" "${pkgdir}/usr/lib/systemd/system/sanoid-prune.service"
}
|