summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e62d5c84cfdf573f3cb115815b1e3c9ec7232daf (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>

pkgname=sawfish-git
pkgver=1.12.90.1.gec0bbea3
pkgrel=1
pkgdesc='A window manager extensible using a Lisp-based scripting language.'
arch=('i686' 'x86_64')
url='http://sawfish.wikia.com'
license=('GPL')
depends=('libsm' 'librep-git' 'rep-gtk-git' 'hicolor-icon-theme' 'libxtst' 'gtk2')
makedepends=('git' 'gettext' 'emacs')
optdepends=('emacs: for using sawfish.el')
provides=('sawfish=1.11')
conflicts=('sawfish')
source=('git://github.com/SawfishWM/sawfish.git' arch_poweroff_defaults.patch)
options=('!libtool')
sha1sums=('SKIP' '73dbf5f93c0124c11f0254267d662f86be1f2767')
_gitname=sawfish

pkgver() {
  cd "$_gitname"
  git describe --tags|sed 's/-/./g'|cut -c9-
}

prepare() {
  cd "$_gitname"
  patch -p1 < "$srcdir"/arch_poweroff_defaults.patch
}

build() {
  cd "$_gitname"
  ./autogen.sh 
  ./configure --prefix=/usr --with-nls 
  make 
  emacs -batch -q -f batch-byte-compile sawfish.el
}

package() {
  cd "$_gitname"
  make DESTDIR="$pkgdir" install 
  install -Dm644 sawfish.el $pkgdir/usr/share/emacs/site-lisp/sawfish.el
  install -Dm644 sawfish.elc $pkgdir/usr/share/emacs/site-lisp/sawfish.elc
  install -Dm644 lisp/sawfish/wm/tile/readme.org \
    $pkgdir/usr/share/doc/$pkgname/readme.tiling.org
}