blob: 7b662399c67b1e698d7c206b7b0c05b842acabe4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Matti Niemenmaa <matti.niemenmaa+aur ät iki dȯt fi>
pkgname=sc68-svn
pkgver=r571
pkgrel=1
pkgdesc="Atari ST and Amiga music player"
arch=(i686 x86_64)
url='http://sc68.atari.org'
license=(GPL2)
depends=(curl libao zlib)
makedepends=(svn)
source=(${pkgname}::svn+svn://svn.code.sf.net/p/sc68/code/)
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$pkgname"
local ver="$(svnversion)"
printf "r%s" "${ver//[[:alpha:]]}"
}
prepare() {
cd "$srcdir/$pkgname"
tools/svn-bootstrap.sh
}
build() {
cd "$srcdir/$pkgname"
(cd as68 && ./configure && make as68)
export PATH="$PWD/as68:$PATH"
for d in unice68 file68 libsc68 sc68; do
pushd $d
./configure --prefix=/usr
make
popd
done
}
package() {
cd "$srcdir/$pkgname"
for d in unice68 file68 libsc68 sc68; do
pushd $d
make install DESTDIR="$pkgdir"
popd
done
}
# vim:set sw=2 et:
|