blob: 1b3e426a9aeb7c93edc29b54c858719ae2983894 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Mikael Blomstrand <gmail: chawlindel>
# Contributor: Jendrik Wenke <jendrikwenke+aur at gmail dot com>
pkgbase=scala-dotty
pkgname=('scala-dotty' 'scala3')
pkgver=3.3.0
pkgrel=1
pkgdesc='The Scala 3 compiler, also known as Dotty.'
arch=('any')
url='http://dotty.epfl.ch'
license=('Apache')
depends=('java-environment>=8')
source=("https://github.com/lampepfl/dotty/releases/download/${pkgver}/scala3-${pkgver}.tar.gz")
sha1sums=('e7dc1b372f40ac8706a6e2961b62ba4a5beeb949')
sha256sums=('064ee508a8e3b9c69843102c836aa89894148022bf37af3c26a9464dfa101475')
b2sums=('523d20e32a6af70899f4db9a0d22744cd4fb22d4250480da3560b16cb48609739131b8bd385284eb091c5d4632ca64fe86ff63a32701916f1999f5f75c5c8cdb')
package_scala3() {
install -d "${pkgdir}/usr/bin" "${pkgdir}/usr/share/scala3/bin"
cp -r "${srcdir}/scala3-${pkgver}/lib" "${pkgdir}/usr/share/scala3"
install -m755 "${srcdir}/scala3-${pkgver}/bin/"* "${pkgdir}/usr/share/scala3/bin"
# Scala 3 symlinks in /usr/bin
ln -s "../share/scala3/bin/scala" "${pkgdir}/usr/bin/scala3"
ln -s "../share/scala3/bin/scalac" "${pkgdir}/usr/bin/scalac3"
ln -s "../share/scala3/bin/scalad" "${pkgdir}/usr/bin/scalad3"
}
package_scala-dotty() {
depends=(scala3)
install -d "${pkgdir}/usr/bin"
# Provide dotty simlinks for convenience
ln -s scala3 "${pkgdir}/usr/bin/dotr"
ln -s scalac3 "${pkgdir}/usr/bin/dotc"
ln -s scalad3 "${pkgdir}/usr/bin/dotd"
}
|