blob: 1ba77f00378e51a6ea2850ce967e86543deeb4ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Allen Choong <allencch at hotmail dot com>
pkgname=scanmem-git
pkgver=0.16.892.5f14e5f
pkgrel=1
pkgdesc='Memory scanner designed to isolate the address of an arbitrary variable in an executing process'
url='https://github.com/scanmem/scanmem'
arch=('i686' 'x86_64')
license=('GPL3')
provides=('scanmem')
conflicts=('scanmem')
depends=('gtk3' 'python-gobject' 'polkit')
makedepends=('git' 'intltool')
source=(${pkgname}::git+https://github.com/scanmem/scanmem.git)
sha512sums=('SKIP')
pkgver() {
cd ${pkgname}
printf "%s.%s.%s" "$(git tag|sort|tail -n1|sed -r 's|-|.|g'|sed -r 's|v?(.*)|\1|')" \
"$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd ${pkgname}
./autogen.sh
}
build() {
cd ${pkgname}
./configure --enable-gui --prefix=/usr
make
}
package() {
cd ${pkgname}
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|