blob: cfe320d34b5d1992e3ba467c65a2137e1bc4c83c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Allen Choong <allencch at hotmail dot com>
pkgname=scanmem-git
pkgver=0.15.4.751.6a5e2e8
pkgrel=1
pkgdesc="Memory scanner designed to isolate the address of an arbitrary variable in an executing process"
url="https://github.com/scanmem/scanmem"
arch=('i686' 'x86_64')
license=('GPL3')
provides=('scanmem')
conflicts=('scanmem')
depends=('pygtk' 'python-gobject' 'polkit')
makedepends=('git' 'intltool')
install=scanmem.install
source=(${pkgname}::git+https://github.com/scanmem/scanmem.git)
sha512sums=('SKIP')
pkgver() {
cd ${pkgname}
printf "%s.%s.%s" "$(git describe --tags --abbrev=0|sed -r 's|-|.|g'|sed -r 's|v?(.*)|\1|')" \
"$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd ${pkgname}
./autogen.sh
./configure --enable-gui --prefix=/usr
make
}
package() {
cd ${pkgname}
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|