blob: 2c206320c9fb01b6442f1b3d2b68a4e7f69097e6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Philipp A. <flying-sheep@web.de>
pkgname=scanpy
pkgver=1.9.1
pkgrel=1
pkgdesc='Single-Cell Analysis in Python'
arch=(any)
provides=(scanpy python-scanpy)
url='https://github.com/theislab/scanpy'
license=(BSD)
depends=(
'python-anndata>=0.7.4'
'python-numpy>=1.17.0'
'python-matplotlib>=3.4'
'python-pandas>=1.0'
'python-scipy>=1.4'
python-seaborn
python-h5py
python-tqdm
'python-scikit-learn>=0.21.2'
'python-statsmodels>=0.10.0'
python-patsy
'python-networkx>=2.3'
python-natsort
python-joblib
'python-numba>=0.41.0'
'python-umap-learn>=0.3.10'
python-packaging
python-sinfo
)
optdepends=(
'python-louvain-igraph: Louvain clustering'
'python-leidenalg: leiden community detection'
'python-bbknn: Batch balanced KNN (batch correction)'
'python-rapids: GPU-driven calculation of neighbors'
'python-magic-impute: MAGIC imputation method'
'python-skmisc: For seurat_v3 highly_variable_genes method'
'python-harmonypy: Harmony dataset integration algorithm'
'python-scanorama: Scanorama dataset integration algorithm'
'python-scrublet: Cell doublet detection'
)
makedepends=(python-build python-installer python-flit-core python-setuptools-scm)
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$pkgname-$pkgver.tar.gz")
sha256sums=('00c9a83b649da7e0171c91e9a08cff632102faa760614fd05cd4d1dbba4eb541')
build() {
cd "$pkgname-$pkgver"
# no idea why the dep check doesn’t work …
python -m build --wheel --no-isolation --skip-dependency-check
}
package() {
cd "$pkgname-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
}
|