PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer:
# Contributor: Dennis Hamester <dennis.hamester@startmail.com>

_pkgname="scd"
pkgname="$_pkgname"
pkgver=0.2.0
pkgrel=3
pkgdesc="Free and open source driver for the Steam Controller"
url="https://gitlab.com/dennis-hamester/scd"
license=('ISC')
arch=('i686' 'x86_64')

depends=(
  'boost-libs'
  'scraw' # AUR
)
makedepends=(
  'boost'
  'cmake'
  'ninja'
  'scrawpp' # AUR
)

_pkgsrc="$_pkgname-v$pkgver"
_pkgext="tar.gz"
source=("$_pkgsrc.$_pkgext"::"$url/-/archive/v$pkgver/$_pkgsrc.$_pkgext")
sha256sums=('1895d4574dc7c789033f77da43622cf493ad4a6e288e89c3fe5ee84c13f0ecf2')

prepare() {
  cd "$_pkgsrc"
  local _files=(
    scd/linux/keyboard.hpp
    scd/linux/mouse.hpp
    scd/linux/xbox360_controller.hpp
  )
  sed -e '1i #include <cstdint>' -i "${_files[@]}"
}

build() {
  local _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX='/usr'
    -DCMAKE_POLICY_VERSION_MINIMUM=3.5
    -Wno-dev
  )

  cmake "${_cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 "$_pkgsrc/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
}