summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 352314b6d4d879e5a7aabc8e7b09cbb9c93921e1 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Dennis Hamester <dennis.hamester@startmail.com>

_pkgname=scd
pkgname=$_pkgname-git
pkgver=0.2.0.r0.g0e7a2de
pkgrel=1
pkgdesc="Free and open source driver for the Steam Controller (git version)"
arch=('i686' 'x86_64')
url="https://gitlab.com/dennis-hamester/scd"
license=('custom:ISC')
makedepends=('cmake' 'scrawpp-git')
depends=('scraw-git')
provides=('scd')
conflicts=('scd')
source=("git+https://gitlab.com/dennis-hamester/scd.git")
sha256sums=('SKIP')

pkgver() {
  cd $_pkgname
  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//g'
}

build() {
  cd $_pkgname
  mkdir build
  cd build
  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    ..
  make
}

package() {
  cd $_pkgname/build
  make DESTDIR="${pkgdir}" install
  install -Dm644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  install -Dm644 ../tinytoml/LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE_tinytoml
}