PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Eleanor Kelley <me at eleanorkelley dot com>

_pkgname=scopebuddy
pkgname=$_pkgname-git
pkgver=1.4.0.r1.g5b64e17
pkgrel=1
pkgdesc="gamescope helper script"
arch=(any)
url="https://github.com/OpenGamingCollective/ScopeBuddy"
license=('Apache-2.0')
depends=(
    'bash'
    'coreutils'
    'gawk'
    'grep'
    'perl'
    'procps-ng'
    'sed'
)
makedepends=('git')
optdepends=(
    'gamescope: gamescope integration'
    'jq: Automatic display detection'
    'libkscreen: Automatic display detection (Plasma)'
    'mutter: Automatic display detection (GNOME)'
    'gnome-randr-rust: Automatic display detection (GNOME fallback)'
    'wlr-randr: Automatic display detection (wlroots)'
)
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("$_pkgname::git+https://github.com/OpenGamingCollective/ScopeBuddy.git")
b2sums=('SKIP')
pkgver() {
    cd $_pkgname
    git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
package() {
    install -Dm755 $_pkgname/bin/scopebuddy "$pkgdir"/usr/bin/scopebuddy
    ln -sf scopebuddy "$pkgdir"/usr/bin/scb
}