summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7ac2d6208befaae7b7adae29b870a4d7ae25ab04 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# $Id$
# Maintainer: Dan Elkouby <streetwalkermc@gmail.com>
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>

_pkgname=scream
pkgname=scream-git
pkgver=3.28.0+47+gc495f1aa8
pkgrel=1
pkgdesc="mutter but it's just an X11 compositor"
url="https://github.com/Streetwalrus/scream"
arch=(x86_64)
license=(GPL)
depends=(libinput zenity libxkbfile libxkbcommon-x11)
makedepends=(intltool git)
conflicts=(mutter)
source=("git+https://github.com/Streetwalrus/scream.git")
sha256sums=('SKIP')

pkgver() {
  cd $_pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $_pkgname

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $_pkgname

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
      --libexecdir=/usr/lib --disable-static \
      --disable-schemas-compile --enable-compile-warnings=minimum

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -e 's/ -shared / -Wl,-O1,--as-needed\0/g' \
      -i {.,cogl,clutter}/libtool

  make
}

package() {
  cd $_pkgname
  make DESTDIR="$pkgdir" install
}