PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Daniel Bermond < gmail-com: danielbermond >

pkgname=screencast-git
pkgver=1.5.0.r25.g5a52a8a
pkgrel=1
pkgdesc='Command line interface to record a X11 desktop (git version)'
arch=('any')
url='https://github.com/dbermond/screencast/'
license=('GPL')
depends=('ffmpeg' 'xorg-xdpyinfo' 'libnotify' 'oxygen-icons')
optdepends=('bc: fade effect support'
            'imagemagick: watermark effect support'
            'slop: graphical screen region selection support'
            'sound-theme-freedesktop: sound notification support'
            'optipng: watermark optimization support'
            'oxipng: watermark optimization support'
            'littleutils-full: watermark optimization support'
            'truepng: watermark optimization support'
            'pingo: watermark optimization support'
            'advancecomp: watermark optimization support'
            'bash-completion: bash-completion support')
makedepends=('git')
checkdepends=('xorg-server-xvfb' 'bc' 'imagemagick' 'ttf-dejavu')
provides=('screencast')
conflicts=('screencast')
source=('git+https://github.com/bermond/screencast.git')
sha256sums=('SKIP')

pkgver() {
    cd screencast
    
    # git, tags available
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

build() {
    cd screencast
    make
}

check() {
    cd screencast
    xvfb-run -n 71 --server-args='-screen 0 1024x768x24' make USEDISPLAY=':71.0' AUDIOIN='none' test
}

package() {
    cd screencast
    make PREFIX='/usr' DESTDIR="$pkgdir" install
}