blob: 856ab3e679095e2f50d69cc32151f809ca5f7ab2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
pkgname=sddm
pkgver=0.17.0
pkgrel=5
pkgdesc='QML based X11 and Wayland display manager'
arch=('x86_64')
url='http://github.com/sddm/sddm'
license=('GPL')
depends=('qt5-declarative' 'xorg-xauth' 'xorg-server')
makedepends=('extra-cmake-modules' 'python-docutils' 'qt5-tools')
backup=('usr/share/sddm/scripts/Xsetup'
'etc/pam.d/sddm')
provides=('display-manager')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v${pkgver}.tar.gz"
sddm.sysusers sddm.tmpfiles)
sha256sums=('c6da2862688d21a091f1568b78a5f5900cd2e02a83dd42c016f0c5867e69a92d'
'9fce66f325d170c61caed57816f4bc72e9591df083e89da114a3bb16b0a0e60f'
'db625f2a3649d6d203e1e1b187a054d5c6263cadf7edd824774d8ace52219677')
prepare() {
mkdir -p build
}
build() {
cd build
cmake ../${pkgname}-${pkgver} \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_LIBEXECDIR=/usr/lib/sddm \
-DDBUS_CONFIG_FILENAME=sddm_org.freedesktop.DisplayManager.conf \
-DBUILD_MAN_PAGES=ON
make
}
package() {
cd build
make DESTDIR="${pkgdir}" install
install -Dm644 "$srcdir"/sddm.sysusers "$pkgdir"/usr/lib/sysusers.d/sddm.conf
install -Dm644 "$srcdir"/sddm.tmpfiles "$pkgdir"/usr/lib/tmpfiles.d/sddm.conf
# Move sddm.conf to /usr/lib https://bugs.archlinux.org/task/56609
mkdir "$pkgdir"/usr/lib/sddm/sddm.conf.d
mv "$pkgdir"/{etc/sddm.conf,usr/lib/sddm/sddm.conf.d}
# Don't set PATH in sddm.conf
sed -r 's|DefaultPath=.*|DefaultPath=/usr/local/sbin:/usr/local/bin:/usr/bin|g' -i "$pkgdir"/usr/lib/sddm/sddm.conf.d/sddm.conf
# Unset InputMethod https://github.com/sddm/sddm/issues/952
sed -e "/^InputMethod/s/qtvirtualkeyboard//" -i "$pkgdir"/usr/lib/sddm/sddm.conf.d/sddm.conf
}
|