blob: c524a564311ee9c7d779ecbac3af9c8d663c7594 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# Maintainer: Tércio Martins <echo dGVyY2lvd2VuZGVsQGdtYWlsLmNvbQo= | base64 -d>
pkgname=sdltrs
pkgver=1.2.15
pkgrel=1
arch=('i686' 'pentium4' 'x86_64')
pkgdesc="TRS-80 Model I/III/4/4P emulator"
url="https://gitlab.com/jengun/sdltrs"
license=('BSD')
depends=('hicolor-icon-theme' 'sdl2')
makedepends=('cmake')
source=("$url/-/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('7a9dd7b97caa46520a9d70b9aaed21d01d8d8483a2d768ef2a39111ff241c45d49f01132553c455e40f6e548966ded83d60fa224f7f951623b9cb7acfe8b49f5')
build() {
[[ -d build ]] && rm -r build
cmake $pkgname-$pkgver \
-Bbuild \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr
cmake --build build
}
package() {
cd build
make DESTDIR="$pkgdir" install
install -dm0755 "$pkgdir/usr/share/licenses/$pkgname"
install -Dm644 "$srcdir/$pkgname-$pkgver/LICENSE" \
-t "$pkgdir/usr/share/licenses/$pkgname"
}
|