blob: b7aa07b9570bb357288bd9b36178e2ee42f98e7a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Přemysl Eric Janouch <p@janouch.name>
pkgname=sdtui-git
_pkgname=sdtui
pkgver=r254.46e9b7b
pkgrel=1
pkgdesc="StarDict TUI and GUI"
url="https://git.janouch.name/p/sdtui"
arch=('i686' 'x86_64')
license=('custom:0BSD')
options=(zipman)
conflicts=('sdtui')
provides=('sdtui')
makedepends=('cmake' 'pkg-config' 'git' 'asciidoctor' 'librsvg')
depends=('zlib' 'glib2' 'ncurses' 'pango')
optdepends=('libxcb: X11 selection watcher' 'gtk3: sdgui')
source=("git+https://git.janouch.name/p/$_pkgname")
md5sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
( set -o pipefail
git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
prepare() {
cd "$srcdir/$_pkgname"
git submodule init
git submodule update
}
build() {
rm -rf "$srcdir/$_pkgname-build"
mkdir "$srcdir/$_pkgname-build"
cd "$srcdir/$_pkgname-build"
cmake "$srcdir/$_pkgname" -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=None
make
}
package() {
cd "$srcdir/$_pkgname-build"
make install DESTDIR=$pkgdir
install -Dm644 "$srcdir/$_pkgname/LICENSE" \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|