blob: 912da16de266207e69aa2a3b16850b7c18867750 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: eolianoe <eolianoe [at] gmail [DoT] com>
# Contributor: Edvinas Valatka <edacval@gmail.com>
# Contributor: Aaron Lindsay <aaron@aclindsay.com>
pkgname=seafile
pkgver=6.1.7
pkgrel=1
pkgdesc="Seafile is an online file storage and collaboration tool"
arch=('i686' 'x86_64' 'armv7h' 'armv6h' 'aarch64')
url="https://github.com/haiwen/${pkgname}"
license=('GPL2')
depends=("ccnet" "fuse" "python2" "sqlite")
makedepends=("vala" "intltool")
conflicts=("seafile-server")
source=("seafile-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz"
"libseafile.in.patch"
"seaf-cli@.service")
sha256sums=('91a4b923155f3ae7c7391d272afec8eebc40866767e45b1ce5a78783a3523fa4'
'a2d7f7cf0c59aba97650af62b3cefd0ceb71a1007c34d9369a88e5769c7f6076'
'c37510109c1de64c774896df39aece240c056b54414d2119fca01860211156ba')
provides=('seafile-client-cli')
prepare () {
cd "${srcdir}/seafile-${pkgver}"
patch -p1 -i "${srcdir}/libseafile.in.patch"
# Fix all script's python 2 requirement
grep -s -l -r '#!/usr/bin/env python' "${srcdir}/seafile-${pkgver}" \
| xargs sed -i -e 's|#!/usr/bin/env python|#!/usr/bin/env python2|g'
}
build() {
cd "$srcdir/seafile-${pkgver}"
./autogen.sh
./configure \
--enable-console \
--prefix=/usr \
PYTHON=/usr/bin/python2
make
}
package() {
cd "${srcdir}/seafile-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm644 "${srcdir}"/seaf-cli@.service "${pkgdir}"/usr/lib/systemd/system/seaf-cli@.service
}
|