blob: cd5b900809a1e54c9dfbd9082676677c296c5e01 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: eolianoe <eolianoe [at] gmail [DoT] com>
# Contributor: Edvinas Valatka <edacval@gmail.com>
# Contributor: Aaron Lindsay <aaron@aclindsay.com>
pkgname=seafile
pkgver=6.0.2
pkgrel=5
pkgdesc="Seafile is an online file storage and collaboration tool"
arch=('i686' 'x86_64' 'armv7h' 'armv6h')
url="https://github.com/haiwen/${pkgname}"
license=('GPL2')
depends=("ccnet" "fuse" "python2" "sqlite")
makedepends=("vala" "intltool")
source=("seafile-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz"
"libseafile.in.patch")
sha256sums=('8ac2eb3611e69b4fd85a9572714153566705c73e443cf2ae24da556c7cf12078'
'a2d7f7cf0c59aba97650af62b3cefd0ceb71a1007c34d9369a88e5769c7f6076')
provides=('seafile-client-cli')
prepare () {
cd "${srcdir}/seafile-${pkgver}"
patch -p1 -i "${srcdir}/libseafile.in.patch"
# Fix all script's python 2 requirement
grep -s -l -r '#!/usr/bin/env python' "${srcdir}/seafile-${pkgver}" \
| xargs sed -i -e 's|#!/usr/bin/env python|#!/usr/bin/env python2|g'
}
build() {
cd "$srcdir/seafile-${pkgver}"
./autogen.sh
./configure \
--enable-console \
--prefix=/usr \
PYTHON=/usr/bin/python2
make
}
package() {
cd "${srcdir}/seafile-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|