1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
# Maintainer: Joffrey <j-off@live.fr>
# Contributor: eolianoe <eolianoe [at] gmail [DoT] com>
# Contributor: Edvinas Valatka <edacval@gmail.com>
# Contributor: Aaron Lindsay <aaron@aclindsay.com>
pkgname=seahub
pkgver=9.0.7
pkgrel=1
pkgdesc='The web frontend for seafile server'
arch=('any')
url='https://github.com/haiwen/seahub'
license=('Apache')
depends=(
"seafile-server>=$pkgver"
'python-django'
'python-future'
'python-django-statici18n'
'gunicorn'
'python-mysqlclient'
'python-django-picklefield'
'python-openpyxl'
'python-qrcode'
'python-django-formtools'
'python-django-simple-captcha'
'python-django-rest-framework'
'python-dateutil'
'python-requests'
'python-pillow'
'python-pyjwt'
'python-pycryptodome'
'python-requests-oauthlib'
'python-django-ranged-response'
'python-chardet'
'python-cffi'
'python-markdown'
)
optdepends=(
'python-pymysql: Installation script'
'python-pysaml2: SSO support'
'python-django-saml2: SSO support'
'python-wsgidav-seafile: Webdav support'
'python-django-pylibmc: Memcached support'
'ffmpeg: For video thumbnails'
)
# Outdated Python modules, but required by Seahub
_thirdpart=(
'django-3.2.15'
'django-webpack-loader-0.7.0'
)
source=(
"$pkgname-$pkgver-server.tar.gz::$url/archive/v$pkgver-server.tar.gz"
"${_thirdpart[0],,}.tar.gz::https://github.com/django/${_thirdpart[0]%-*}/archive/${_thirdpart[0]##*-}.tar.gz"
"${_thirdpart[1],,}.tar.gz::https://github.com/django-webpack/${_thirdpart[1]%-*}/archive/${_thirdpart[1]##*-}.tar.gz"
'seahub@.service'
'nginx.example.conf'
)
sha256sums=(
'eb6b49f961514053e417a93e098e6d8c01186ae71556916bdf4b784939db8022'
'371f4f008b7c572bf7d78c564836f0bcd698fd9bc967807c7fbe4f65696d7df5'
'fef6b13bbd61d682e12f3bd73bb7ac1c398dd0dea22ef2cf34309c6d1078b0d1'
'67bb375871ce908b48bef53277284c9d8f80ee2e733efc89cb66d987647195e4'
'461591ba500d012523d6fdecbcc230461f6fd8d708b92eefdedc8b93b1542171'
)
options=('!strip')
prepare() {
cd "$srcdir/$pkgname-$pkgver-server"
# Remove useless files and directories
rm -rf \
./{CONTRIBUTORS,HACKING,Makefile} \
./{*test*,*dev*,*sh*,README*,pylintrc*,LICENSE*} \
./scripts/{build,pro.py,*.{md,conf}}
find . -type f \( -name '*.pyc' -o -name '.git*' \) -delete
# Fix paths to Gunicorn
sed -e 's|gunicorn_exe=.*|gunicorn_exe=/usr/bin/gunicorn|g' \
-e 's|thirdpart/bin/gunicorn|$gunicorn_exe|g' \
-i ./scripts/seahub.sh
sed -i -E "/SEAFILE_VERSION/s/[0-9.]+/$pkgver/" ./seahub/settings.py
}
build() {
cd "$srcdir/$pkgname-$pkgver-server"
for locale in ./locale/*/LC_MESSAGES/*.po; do
echo "$locale"
msgfmt -vo "${locale%.po}.mo" "$locale"
done
}
package() {
cd "$srcdir/seahub-$pkgver-server/"
install -dm755 "$pkgdir/usr/share/seafile-server/seahub"
cp -rp ./* "$pkgdir/usr/share/seafile-server/seahub"
mv "$pkgdir/usr/share/seafile-server/seahub/scripts/"* \
"$pkgdir/usr/share/seafile-server"
# Install third part
for thirdpart in "${_thirdpart[@]}"; do
cd "$srcdir/$thirdpart"
python setup.py install \
--root="$pkgdir/" \
--install-lib="usr/share/seafile-server/$pkgname/thirdpart" \
--optimize=0
done
rm -rf "$pkgdir"/usr/{bin,share/seafile-server/"$pkgname"/thirdpart/*.egg-info}
python -m compileall -f -j 0 -o 1 \
-s "$pkgdir" -p / "$pkgdir/usr/share/seafile-server/seahub"
install -Dm644 \
"$srcdir/seahub@.service" \
"$pkgdir/usr/lib/systemd/system/seahub@.service"
install -Dm644 \
"$srcdir/nginx.example.conf" \
"$pkgdir/etc/webapps/$pkgname/nginx.conf"
}
|