blob: 0dbd224563cac1254e94c328ab763f27570eaa60 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Jonathon Fernyhough <jonathon+m2x.dev>
# Contributor: krevedko <helllamer-gmail.com>
pkgname=seaweedfs
pkgver=3.15
pkgrel=1
pkgdesc="SeaweedFS is a simple and highly scalable distributed file system"
arch=('i686' 'x86_64' 'aarch64' 'armv7h' 'armv6h' 'arm')
url="https://github.com/chrislusf/seaweedfs"
license=('APACHE')
makedepends=('git' 'go')
options=('!lto')
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
b2sums=('fb6ac9827b51b460aa42935ae1e55869969307bfcd2c37dad118b136564033bf0fe699de68b98ca3cc1e09cdbc93583c018ce4da61b21b8a7e14396dcb702ad8')
_shortcommit=5799a20
prepare() {
cd $pkgname-$pkgver
export GOPATH="${SRCDEST:-$srcdir}"
go mod vendor
}
build() {
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS="-buildmode=pie -trimpath -mod=vendor -modcacherw"
export GOPATH="${SRCDEST:-$srcdir}"
cd $pkgname-$pkgver/weed
go build -v $GO_FLAGS -tags 5BytesOffset -ldflags "-X github.com/chrislusf/seaweedfs/weed/util.COMMIT=$_shortcommit -extldflags $LDFLAGS"
}
#check() {
# cd $pkgname-$pkgver/weed
# go test -v
#}
package() {
cd $pkgname-$pkgver
install -D weed/weed "$pkgdir"/usr/bin/weed
install -Dm644 README.md "$pkgdir"/usr/share/doc/$pkgname/README.md
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|