blob: aab5b4ea6178b12747b9d7510a23ebd7597c2311 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
pkgname=seaweedfs
pkgver=1.82
pkgrel=1
pkgdesc="SeaweedFS is a simple and highly scalable distributed file system"
arch=('i686' 'x86_64' 'aarch64' 'armv7h' 'armv6h' 'arm')
url="https://github.com/chrislusf/seaweedfs"
license=('APACHE')
makedepends=('go')
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz"
ldflags.patch)
sha256sums=('9660f9296b57dd790f3970b8f2fb03c0bbdc54c563081105104ab713441acf2c'
'64db3c34767099aab8ec385c0b6796a2745ed66fa35159df0e8108da31e710db')
prepare() {
cd $pkgname-$pkgver
patch -Np1 -i ../ldflags.patch
export GOPATH="${SRCDEST:-$srcdir}"
go mod vendor
}
build() {
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS="-buildmode=pie -trimpath -mod=vendor -modcacherw"
cd $pkgname-$pkgver
make GOPATH="${SRCDEST:-$srcdir}"
}
package() {
cd $pkgname-$pkgver
install -D weed/weed "$pkgdir"/usr/bin/weed
install -Dm644 README.md "$pkgdir"/usr/share/doc/$pkgname/README.md
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|