blob: 7b6b6797840ec11365ad21372df0fdeba605a718 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: Mauro Santos <registo.mailling@gmail.com>
pkgname=sedutil
pkgver=1.12
pkgrel=6
pkgdesc="TCG OPAL 2.00 SED Management Program"
arch=('i686' 'x86_64')
url="https://github.com/Drive-Trust-Alliance/sedutil"
license=('GPL3')
optdepends=('syslinux: to create a bootable PBA disk image'
'gptfdisk: to create a bootable PBA disk image'
'parted: to create a bootable PBA disk image'
'intel-ucode: microcode update files for Intel CPUs'
'yubikey-personalization: for yubikey support')
backup=('etc/linuxpba/linuxpba.conf')
install=sedutil.install
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/Drive-Trust-Alliance/${pkgname}/archive/${pkgver}.tar.gz"
'syslinux.cfg'
'mklinuxpba-initramfs'
'mklinuxpba-diskimg'
'linuxpba-arch'
'linuxpba.conf.etc'
'linuxpba.conf.lib'
'linuxpba.hook'
'linuxpba.install'
'getpasswd.c'
'nvme_ioctl.patch::https://github.com/bcarmo-caio/sedutil/commit/5ca6100917a025f6e11ae20838e1e37e7db2d587.patch')
sha256sums=('5509d4279cfb316f33730c5cb06f8162ae212c7f4d31d206642d67cc8be245c1'
'40d785c16a28a5a8a43050d1731174482ee24459be215d2e4e27ffba3b2e28b2'
'77c725e4eee095dbede512d2bca13b8f2c139a67b9b87a11d98be94e6df0e1d7'
'b860d4d6fcc14a61d110c1d805d919fdfcf0fffaa8f0175b5ecddf60051f7941'
'6207ef94a25b5b86890f60e003a10686e9fc8705b7e071f7dd75080c14d8ee00'
'6bf64faa4e413bac489e83518daf6963760cc4474ea2b848d0192402214c0efb'
'a110e6d6da0fd658412d8c79f7f2cbc58a9b0067c34c34c94c8f623801eecc78'
'd9a7b66d8365e7f4eb0233b30c0ab70b5e978f6554960bf12994a1f0910c1447'
'f31a0ba891dd705ef68174afeb651bdc3426a63202d058d98510907de43248f7'
'e94d011c98bd336f37d6d4923e5d63a22ebd10d8f2c6486b6bcd6617524d6484'
'ef179c054ed79399cdb2cdf9e43e565d5556891e7676b795e55d126b2641a919')
CPPFLAGS="$CPPFLAGS -O2"
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}/"
patch -p1 < "${srcdir}/nvme_ioctl.patch"
}
build() {
_release="Release_$CARCH"
cd "${srcdir}/"
gcc -Wall -o getpasswd getpasswd.c
cd "${srcdir}/${pkgname}-${pkgver}/linux/CLI/"
make CONF="${_release}" build
cd "${srcdir}/${pkgname}-${pkgver}/LinuxPBA/"
[[ "$CARCH" == "i686" ]] && _release="Release"
make CONF="${_release}" build
}
package() {
_release="Release_$CARCH"
cd "${srcdir}/${pkgname}-${pkgver}/"
install -Dm755 "linux/CLI/dist/${_release}/GNU-Linux/sedutil-cli" "${pkgdir}/usr/bin/sedutil-cli"
install -Dm644 "linux/PSIDRevert_LINUX.txt" "${pkgdir}/usr/share/doc/${pkgname}/PSIDRevert.txt"
[[ "$CARCH" == "i686" ]] && _release="Release"
install -Dm755 "LinuxPBA/dist/${_release}/GNU-Linux/linuxpba" "${pkgdir}/usr/bin/linuxpba"
install -Dm755 "${srcdir}/mklinuxpba-initramfs" "${pkgdir}/usr/bin/mklinuxpba-initramfs"
install -Dm755 "${srcdir}/mklinuxpba-diskimg" "${pkgdir}/usr/bin/mklinuxpba-diskimg"
install -Dm755 "${srcdir}/linuxpba-arch" "${pkgdir}/usr/bin/linuxpba-arch"
install -Dm755 "${srcdir}/getpasswd" "${pkgdir}/usr/bin/getpasswd"
install -Dm644 "${srcdir}/linuxpba.hook" "${pkgdir}/usr/lib/initcpio/hooks/linuxpba"
install -Dm644 "${srcdir}/linuxpba.install" "${pkgdir}/usr/lib/initcpio/install/linuxpba"
install -Dm644 "${srcdir}/linuxpba.conf.etc" "${pkgdir}/etc/linuxpba/linuxpba.conf"
install -Dm644 "${srcdir}/linuxpba.conf.lib" "${pkgdir}/usr/lib/linuxpba/linuxpba.conf"
install -Dm644 "${srcdir}/syslinux.cfg" "${pkgdir}/usr/lib/linuxpba/syslinux.cfg"
}
|