blob: e2de3578c5b307cd9d6150e9cc022ee450978c80 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Benjamin A. Shelton <zancarius@gmail.com>
# Source: https://github.com/zancarius/archlinux-pkgbuilds
pkgname=sentry
pkgver=8.1.2
pkgrel=1
pkgdesc="Python-based realtime logging and aggregation server."
arch=(any)
url="http://pypi.python.org/pypi/sentry"
license=(BSD)
depends=(
jansson
python2
redis
)
makedepends=(python2-pip python2-setuptools python2-virtualenv)
optdepends=(
'mariadb: MySQL backend support'
'postgresql: PostgreSQL backend support'
'sqlite: SQLite backend support'
)
options=(!strip)
install="${pkgname}.install"
source=(
"${pkgname}.install"
"sentry.service"
"sentry-celery.service"
)
md5sums=(
a923b21928a227eda35dd76d599fbac1 # sentry.install
8d1d8d166a88bc89ad2265fd67ab3523 # sentry.service
78dd3e18109c2bf92f7f884de0237781 # sentry-celery.service
)
package () {
mkdir -p "${pkgdir}/opt/sentry"
virtualenv2 --python=python2.7 "${pkgdir}/opt/sentry"
source "${pkgdir}/opt/sentry/bin/activate"
# Begin Sentry installation for our specific version via PyPI. This
# guarantees we'll grab all of the appropriate dependencies and
# automates the process.
"${pkgdir}/opt/sentry/bin/pip" install "sentry==${pkgver}"
# Make certain the virtualenv is relocatable.
virtualenv2 --relocatable "${pkgdir}/opt/sentry"
sed -i "s#${pkgdir}##" "${pkgdir}/opt/sentry/bin/activate"
mkdir -p "${pkgdir}/opt/sentry/.python-eggs"
mkdir -p "${pkgdir}/etc/sentry"
# Remove Desktop Services Store from package. At least one of these files
# still persists in the Sentry package. They're harmless, but I don't like
# them. :) More information: http://en.wikipedia.org/wiki/.DS_Store
find "${pkgdir}" -name '.DS_Store' -delete
install -Dm0644 "${srcdir}/sentry.service" "${pkgdir}/usr/lib/systemd/system/sentry.service"
install -Dm0644 "${srcdir}/sentry-celery.service" "${pkgdir}/usr/lib/systemd/system/sentry-celery.service"
}
|