PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Janek Graff <janek.graff at gmx dot com>
# This is a modified version of xorlys' serialplot-hg package (https://aur.archlinux.org/packages/serialplot-hg)
# It changes the upstream to the git repository and uses the qwt dependency that is delivered by the build process of serialplot
pkgname=serialplot-git
_pkgname=serialplot
pkgver=v0.13.0.r4.gdc6efa6
pkgrel=1
pkgdesc="Small and simple software for plotting data from serial port in realtime"
arch=('i686' 'x86_64')
url="https://github.com/hyOzd/serialplot"
license=('GPL3')
depends=('qt6-base' 'qt6-serialport' 'qt6-svg' 'hicolor-icon-theme')
makedepends=('git' 'cmake' 'make')
provides=('serialplot')
conflicts=('serialplot-hg')
source=('git+https://github.com/hyOzd/serialplot.git')
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  (
    set -o pipefail
    git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
      printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  cd "$srcdir/$_pkgname"
  mkdir -p build
  cd build
  local cmake_options=(
    -B build
    -S "${srcdir}/${_pkgname}"
    -DCMAKE_CXX_FLAGS=-DUPDATE_TYPE_PKGMAN
    -DCMAKE_INSTALL_PREFIX='/usr'
    -Wno-dev
  )
  cmake "${cmake_options[@]}"
  cmake --build build
}

package() {
  cd "$srcdir/$_pkgname"
  cd build
  DESTDIR="$pkgdir" cmake --install build
}