blob: dda89172335b26e174f9a8df7e668c6cf624b3d9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: oi_wtf <brainpower at mailbox dot org>
pkgname=sfml-git
pkgver=2.4.0.r37.g858c9ce9
pkgrel=1
pkgdesc="A simple, fast, cross-platform, and object-oriented multimedia API"
arch=('i686' 'x86_64')
url="http://www.sfml-dev.org/"
license=('zlib')
depends=('libsndfile' 'libxrandr' 'libjpeg' 'openal' 'glew' 'freetype2' 'xcb-util-image')
makedepends=('mesa' 'cmake' 'doxygen' 'git')
provides=('sfml')
conflicts=('sfml')
replaces=('sfml')
options=('debug')
source=("git+https://github.com/SFML/SFML.git"
"0001-fix_cmake_module_install_path.patch")
sha256sums=('SKIP'
'c0be2636b1d342f636f2587e043dbfa8becdd8d9c65044cf7749ab4b2c81eb47')
pkgver() {
cd "${srcdir}/SFML"
git describe --long --tags | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
}
prepare() {
cd "$srcdir/SFML"
patch -p0 -i "$srcdir/0001-fix_cmake_module_install_path.patch"
}
build() {
cd "$srcdir/SFML"
cmake -DCMAKE_INSTALL_PREFIX=/usr . \
-DCMAKE_BUILD_TYPE=RelWithDebugInfo \
-DBUILD_DOC=true \
-DBUILD_EXAMPLES=false
make
make doc
}
package() {
cd "$srcdir/SFML"
make DESTDIR="$pkgdir/" install
install -Dm644 ./license.md ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md
}
# vim:set ts=2 sw=2 et:
|