summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 675f7752edbf6935696fd3524a0144940dbc10ec (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Maintainer: Vain <aurmaint1 on host: uninformativ dot de>
_pkgname=sgopherd
pkgname=$_pkgname-git
pkgver=15.03
pkgrel=1
pkgdesc="A gopher server written in Bash"
arch=('any')
url="https://github.com/vain/sgopherd"
license=('custom:PIZZA-WARE')
depends=('bash')
makedepends=('git')
backup=('etc/xinetd.d/sgopherd')
optdepends=('xinetd: Traditional way to run sgopherd'
            'systemd: sgopherd also works with socket activation')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=(git://github.com/vain/sgopherd.git)
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  git describe --always | sed 's|-|.|g; s|v||'
}

package() {
  cd "$srcdir/$_pkgname"

  install -Dm755 sgopherd "$pkgdir"/usr/bin/sgopherd

  install -Dm644 xinetd/xinetd-example.conf "$pkgdir"/etc/xinetd.d/sgopherd

  install -Dm644 systemd/sgopherd@.service \
    "$pkgdir"/usr/lib/systemd/system/sgopherd@.service
  install -Dm644 systemd/sgopherd.socket \
    "$pkgdir"/usr/lib/systemd/system/sgopherd.socket
  install -Dm755 systemd/sgopherd-systemd \
    "$pkgdir"/usr/bin/sgopherd-systemd

  install -Dm644 man8/sgopherd.8 "$pkgdir"/usr/share/man/man8/sgopherd.8
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et: