blob: b88d8bcc0debc3d136ef51f8c3711e4973112086 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer 2021-2021: 4679 <4679@pm.me>
# Maintainer 2022-: spyophobia <76800505+spyophobia@users.noreply.github.com>
# Co-Maintainer: DuckSoft <realducksoft@gmail.com>
pkgname=shadowsocks-rust-bin
_pkgname=shadowsocks-rust
pkgver=1.14.3
pkgrel=6
pkgdesc='A Rust port of shadowsocks https://shadowsocks.org/ (binary version)'
arch=('x86_64' 'arm' 'aarch64')
url='https://github.com/shadowsocks/shadowsocks-rust'
license=('MIT')
depends=('gcc-libs')
provides=("${_pkgname}")
conflicts=("${_pkgname}" "${_pkgname}-git")
source=(
"${url}/raw/v${pkgver}/LICENSE"
'shadowsocks-rust-local@.service.system'
'shadowsocks-rust-server@.service.system'
'shadowsocks-rust-local@.service.user'
'shadowsocks-rust-server@.service.user'
"${url}/raw/v${pkgver}/examples/config.json"
"${url}/raw/v${pkgver}/examples/config_ext.json"
)
source_x86_64=("${url}/releases/download/v${pkgver}/shadowsocks-v${pkgver}.x86_64-unknown-linux-gnu.tar.xz")
source_arm=("${url}/releases/download/v${pkgver}/shadowsocks-v${pkgver}.arm-unknown-linux-gnueabi.tar.xz")
source_aarch64=("${url}/releases/download/v${pkgver}/shadowsocks-v${pkgver}.aarch64-unknown-linux-gnu.tar.xz")
sha512sums=(
'6d7014061bf4014faec823aa1da91f990d034c21005cbee30de7ee62744201fba7d09d58a9e536d8e63bfa6fe951107ee68482b583d887b6e358f3c3eec89b85'
'87e637edaa601da208366806fb8e16f6783b2b2f066b17c453274153b91ead66eea6caae9f82c3e2118bce3230d0812a47e540670c219bcc49d2296a102cf1dd'
'fcc40b1c864179916c1691b57e98fd8e1519047b87ea5b37dba52fd340869208f493f0c83e941dcfd5de22851db1302d97765e9ddcd5174fd8b1fabece5e1963'
'6301ac089707d6c253bec5ca3a9b554e5965acd7cb04ba52abcd44367dde4f59fba1343ca45b8294960c39a6c56afccdf9d6e6e3411dde8c5d78be05bfeeb107'
'5dee5fc5f0542a38fef7146100bf05f28ae074d8a2ed411b46a2d99396668fd8880ea83fb759d91cf17669eef997af6ccbc3b34a4d4c528808b1fe9f7947a969'
'9a0b81d82bf897c5461d75d941cd604cbd7f32d00c2bf775f17b37b77fcf5734903d2ec666ba9a6a340e77f31018b5dbbb8ea597797c6a00c6b1f3e2f47127e6'
'4ac52e6fe04e02543f54d57fccfd863f18b157fd28fb61c9a56ba46269b9dff410a80960943d911afa55b45c3fc42e98d91f8bb75e9103abf3f3dbfffb73a6e0'
)
sha512sums_x86_64=('e43523d9ea7cab08a3634a7df38c51b7121f205bc1318c577233ef7004e82efb0152883eec40658f731719707577a0381e09557bc407890966f1feb886527e33')
sha512sums_arm=('6ae0001efcc58756e06889c65165b78baa2a0a061af428cc57cd9b24b258966c6d755e9d5f87a88e4ebd4b499104edc335e6c9736d78afd46b114a6ecfd8db37')
sha512sums_aarch64=('2cd040b43f1e76b46d4d25be5ddc76805dc6e64016ad676c6281f44ce65fa1993294b076ff48a35007c30de69c098b4ca07d0dcd7f9917af2b852baa2caa8f47')
package() {
cd "${srcdir}"
install -Dm755 -t "${pkgdir}/usr/bin" sslocal ssserver ssurl ssmanager ssservice
install -Dm644 -t "${pkgdir}/usr/share/licenses/$pkgname" LICENSE
install -Dm644 shadowsocks-rust-local@.service.system "${pkgdir}/usr/lib/systemd/system/shadowsocks-rust-local@.service"
install -Dm644 shadowsocks-rust-server@.service.system "${pkgdir}/usr/lib/systemd/system/shadowsocks-rust-server@.service"
install -Dm644 shadowsocks-rust-local@.service.user "${pkgdir}/usr/lib/systemd/user/shadowsocks-rust-local@.service"
install -Dm644 shadowsocks-rust-server@.service.user "${pkgdir}/usr/lib/systemd/user/shadowsocks-rust-server@.service"
install -Dm644 config.json "${pkgdir}/etc/shadowsocks/config_rust.json.example"
install -Dm644 config_ext.json "${pkgdir}/etc/shadowsocks/config_ext_rust.json.example"
}
|