blob: 053cda90a164d14439525c0596e90d4c18590b71 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
pkgname=shadowvpn
pkgver=0.1.6
pkgrel=1
pkgdesc="A fast, safe VPN based on libsodium"
arch=('i686' 'x86_64')
url="https://github.com/clowwindy/ShadowVPN"
license=('MIT')
depends=('sh' 'libsodium')
makedepends=('git')
options=('!emptydirs')
backup=('etc/shadowvpn/client.conf'
'etc/shadowvpn/client_down.sh'
'etc/shadowvpn/client_up.sh'
'etc/shadowvpn/server.conf'
'etc/shadowvpn/server_down.sh'
'etc/shadowvpn/server_up.sh')
source=("git+https://github.com/clowwindy/ShadowVPN.git#tag=$pkgver")
md5sums=('SKIP')
prepare() {
cd ShadowVPN
rmdir libsodium
sed -e 's|SUBDIRS = ../libsodium||' \
-e 's|AM_CFLAGS = .*libsodium.*$|AM_CFLAGS = -lsodium|' \
-e 's|libshadowvpn_la_LIBADD = ../libsodium/src/libsodium/libsodium.la||' \
-i src/Makefile.am
sed -e 's|AC_CONFIG_SUBDIRS([libsodium])||' \
-i configure.ac
}
build() {
cd ShadowVPN
./autogen.sh
./configure --sysconfdir=/etc --disable-static --prefix=/usr
make
}
package() {
cd ShadowVPN
make DESTDIR="$pkgdir" install
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|