PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

# Maintainer: MaxCrazy <alex02newton@gmail.com>

pkgname=shatv-git
pkgver=0.1.0.r88.gd4729d7
pkgrel=1
pkgdesc='Qt-based IPTV player with sherpa-onnx speech recognition'
arch=('x86_64')
url='https://github.com/MaxCrazy1101/shatv'
license=('MIT')
depends=(
  'ffmpeg'
  'gcc-libs'
  'glibc'
  'hicolor-icon-theme'
  'libarchive'
  'onnxruntime'
  'qt6-base'
  'qt6-declarative'
  'qt6-multimedia'
  'qt6-shadertools'
  'sherpa-onnx'
  'zlib'
)
makedepends=(
  'cmake'
  'git'
  'ninja'
  'pkgconf'
  'qt6-tools'
  'toml11'
)
provides=('shatv' 'shatv-asr')
conflicts=('shatv' 'shatv-bin' 'shatv-asr' 'shatv-asr-bin')
source=('git+https://github.com/MaxCrazy1101/shatv.git')
sha256sums=('SKIP')

pkgver() {
  cd shatv
  local describe
  if describe=$(git describe --long --tags --abbrev=7 2>/dev/null); then
    printf '%s' "$describe" | sed 's/^v//;s/-/.r/;s/-/./'
  else
    printf '0.1.0.r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
  fi
}

build() {
  cmake -S shatv -B build -G Ninja \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_TESTING=OFF \
    -DSHATV_ENABLE_ASR=ON \
    -DSHATV_SHERPA_ONNX_ROOT=/usr \
    -DSHATV_ONNXRUNTIME_ROOT=/usr \
    -DSHATV_REQUIRE_LIBARCHIVE=ON \
    -DSHATV_FETCH_TOML11=OFF \
    -DSHATV_FETCH_ZLIB=OFF \
    -DSHATV_LINUX_PACKAGE_DISTRIBUTION=arch
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}