PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Davide Depau <davide@depau.eu>

_pkgname=shcrt
pkgname=$_pkgname-git
pkgver=r23.bd960a6
pkgrel=1
pkgdesc="Replace proprietary SecureCRT software with a Bash script that parses its configs"
arch=('any')
depends=('bash' 'easybashgui' 'python' 'python-pycrypto')
url="https://github.com/Depau/shcrt"
license=('GPL3')
source=(${_pkgname}::git+https://github.com/Depau/shcrt.git)
sha256sums=('SKIP')
provides=($_pkgname)
conflicts=($_pkgname)

pkgver() {
  cd "$_pkgname"
  ( set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

package() {
  cd "$srcdir/${_pkgname}"
  
  install -dm755 "$pkgdir/usr/share/shcrt"
  install -m755 shcrt "$pkgdir/usr/share/shcrt/shcrt"
  install -m755 crt2foss.py "$pkgdir/usr/share/shcrt/crt2foss.py"
  install -m755 SecureCRTCipher.py "$pkgdir/usr/share/shcrt/SecureCRTCipher.py"

  install -dm755 "$pkgdir/usr/bin"
  ln -sf /usr/share/shcrt/shcrt "$pkgdir/usr/bin/shcrt"
  ln -sf /usr/share/shcrt/crt2foss.py "$pkgdir/usr/bin/crt2foss"
  ln -sf /usr/share/shcrt/SecureCRTCipher.py "$pkgdir/usr/bin/SecureCRTCipher.py"
}