blob: d1b783ca26baa730371825b44f7e06437b42e7cb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
|
# Maintainer: Zoey Bauer <zoey.erin.bauer@gmail.com>
# Maintainer: Caroline Snyder <hirpeng@gmail.com>
pkgbase=shelly-bin
pkgname=('shelly-bin' 'shelly-flatpak-backend-bin')
pkgver=3.1.6
pkgrel=1
arch=('x86_64')
url="https://github.com/Seafoam-Labs/Shelly-ALPM"
license=('GPL-3.0-only')
makedepends=('go-md2man')
source=(
"Shelly-ALPM-linux-x64-${pkgver}.tar.gz::https://github.com/Seafoam-Labs/Shelly-ALPM/releases/download/v${pkgver}/Shelly-ALPM-linux-x64.tar.gz"
"Shelly-Flatpak-Backend-linux-x64-${pkgver}.tar.gz::https://github.com/Seafoam-Labs/Shelly-ALPM/releases/download/v${pkgver}/Shelly-Flatpak-Backend-linux-x64.tar.gz"
'shellybuild.conf'
'com.shellyorg.shelly.desktop'
'com.shellyorg.shelly-notifications.desktop'
'shelly-flatpak-integrate'
)
sha256sums=('cd6443eb5cce22560dca583b4b935891379e8b8ce4836f3ba85eaa52adb6da47'
'8919be4c25f56c28c3b037c656c6a600b0f600cd9edb74fee128babecc59acfe'
'd7adb207c0073b93679ff3b8741a734ab62b48283134465b47844884bd211bb9'
'a86884190d69b483376bf4f7b224483cae7fc5a65b61f98e46e805f838e053ed'
'cf0dc0a6d1865b9010054b36941e7bf4d445c3e7549219889f07ab08283c5c0f'
'07bca40395c180578450c523ea052b036aa8197d8a871efcce55f937c101c323')
package_shelly-bin() {
pkgdesc="Shelly: A Modern Arch Package Manager (prebuilt binary)"
provides=('shelly')
conflicts=('shelly' 'shelly-git')
backup=('etc/shellybuild.conf')
depends=(
'pacman'
'gtk4'
'glib2'
'sudo'
'tar'
'bash'
'git'
'hicolor-icon-theme'
'dbus'
'glibc'
'libarchive'
'dconf'
'gnupg'
'zstd'
'json-glib'
)
optdepends=(
'fish: Fish shell completions'
'zsh: Zsh shell completions'
'libstarfish: dependency viewer for arch packages'
'shelly-flatpak-backend-bin: Flatpak package management support'
'util-linux: isolate fresh-root provisioning for --isolated builds'
'fuse2: run AppImages that require FUSE 2'
)
# Install Shelly.Gtk binary
install -Dm755 "$srcdir/shelly-ui" "$pkgdir/usr/bin/shelly-ui"
# Install Shelly-Notifications binary
install -Dm755 "$srcdir/shelly-notifications" "$pkgdir/usr/bin/shelly-notifications"
# Install Shelly.Cli binary
install -Dm755 "$srcdir/shelly" "$pkgdir/usr/bin/shelly"
# Install Shelly.Key binary
install -Dm755 "$srcdir/shelly-key" "$pkgdir/usr/bin/shelly-key"
install -Dm644 "$srcdir/shellybuild.conf" "$pkgdir/etc/shellybuild.conf"
# Install desktop entries
install -Dm644 "$srcdir/com.shellyorg.shelly.desktop" \
"$pkgdir/usr/share/applications/com.shellyorg.shelly.desktop"
install -Dm644 "$srcdir/com.shellyorg.shelly-notifications.desktop" \
"$pkgdir/usr/share/applications/com.shellyorg.shelly-notifications.desktop"
# Ensure the polkit directory exists
install -m0755 -d "${pkgdir}"/usr/share/polkit-1/actions
# Install Polkit policy for privileged Shelly CLI execution via pkexec
cat <<'EOF' | install -Dm644 /dev/stdin "$pkgdir/usr/share/polkit-1/actions/com.shellyorg.shelly.policy"
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE policyconfig PUBLIC "-//freedesktop//DTD PolicyKit Policy Configuration 1.0//EN"
"http://www.freedesktop.org/standards/PolicyKit/1.0/policyconfig.dtd">
<policyconfig>
<vendor>Shelly</vendor>
<vendor_url>https://github.com/Seafoam-Labs/Shelly-ALPM</vendor_url>
<action id="com.shellyorg.shelly.pkexec.cli">
<description>Run Shelly CLI as administrator</description>
<message>Run Shelly CLI with administrator privileges.</message>
<icon_name>shelly</icon_name>
<defaults>
<allow_any>auth_admin</allow_any>
<allow_inactive>auth_admin</allow_inactive>
<allow_active>auth_admin_keep</allow_active>
</defaults>
<annotate key="org.freedesktop.policykit.exec.path">/usr/bin/shelly</annotate>
</action>
</policyconfig>
EOF
# Install icon
install -Dm644 "$srcdir/shellylogo.png" "$pkgdir/usr/share/icons/hicolor/256x256/apps/shelly.png"
install -Dm644 "$srcdir/shellylogo-tray.png" "$pkgdir/usr/share/icons/hicolor/256x256/apps/shelly-tray.png"
install -Dm644 "$srcdir/shellylogo-update.png" "$pkgdir/usr/share/icons/hicolor/256x256/apps/shelly-update.png"
# Install fish shell completions
install -Dm644 "$srcdir/shelly.fish" "$pkgdir/usr/share/fish/vendor_completions.d/shelly.fish"
# Install zsh shell completions
install -Dm644 "$srcdir/_shelly" "$pkgdir/usr/share/zsh/site-functions/_shelly"
# Install man page
"$srcdir/shelly" utility --docs | go-md2man > "$srcdir/shelly.1"
sed -i "s|^\\.TH .*|.TH \"SHELLY\" \"1\" \"\" \"Shelly ${pkgver}\" \"Shelly CLI Manual\"|" "$srcdir/shelly.1"
printf '\n.SH AUTHORS\nSeafoam Labs.\n' >> "$srcdir/shelly.1"
install -Dm644 "$srcdir/shelly.1" "$pkgdir/usr/share/man/man1/shelly.1"
# Install translations
if [ -d "$srcdir/locale" ] && [ -n "$(ls -A "$srcdir/locale" 2>/dev/null)" ]; then
install -d "$pkgdir/usr/share/locale"
cp -r "$srcdir/locale/."/* "$pkgdir/usr/share/locale/" 2>/dev/null || true
fi
# Install Flatpak integration script
install -Dm755 "$srcdir/shelly-flatpak-integrate" \
"$pkgdir/usr/bin/shelly-flatpak-integrate"
}
package_shelly-flatpak-backend-bin() {
pkgdesc="Optional native Flatpak backend for Shelly (prebuilt binary)"
depends=("shelly-bin=${pkgver}-${pkgrel}" 'flatpak')
provides=("shelly-flatpak-backend=${pkgver}")
conflicts=('shelly-flatpak-backend' 'shelly-flatpak-backend-git')
install -Dm755 \
"$srcdir/libshelly-flatpak-backend.so.1.0.0" \
"$pkgdir/usr/lib/shelly/libshelly-flatpak-backend.so.1.0.0"
ln -s libshelly-flatpak-backend.so.1.0.0 \
"$pkgdir/usr/lib/shelly/libshelly-flatpak-backend.so.1"
}
|