blob: 79461209d0cacc08c2bbfb726c49191749b64470 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Previous maintainer: Leonard de Ruijter <alderuijter@gmail.com>
# Contributor: Matthias Grosser <mtgrosser at gmx dot net>
pkgname=shine-git
pkgver=3.1.1.r59.gab5e352
pkgrel=1
pkgdesc="Super fast fixed-point MP3 encoder"
arch=('i686' 'x86_64')
url="https://github.com/toots/shine"
license=('GPL-2.0-or-later')
depends=('glibc')
makedepends=('git')
provides=("shine=$pkgver")
conflicts=('shine')
options=('staticlibs')
source=("git+https://github.com/toots/shine.git")
sha256sums=('SKIP')
pkgver() {
cd "shine"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "shine"
./bootstrap
./configure \
--prefix="/usr"
make
}
check() {
cd "shine"
make check
}
package() {
cd "shine"
make DESTDIR="$pkgdir" install
}
|