blob: 50d5443a305469e92a4fa1147764c50d8c4997af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
pkgname=('shotcut-git')
srcname='shotcut'
pkgdesc='Video editor'
pkgver='r1'
pkgrel='1'
arch=('i686' 'x86_64')
url='https://github.com/mltframework/shotcut'
license=('GPL3')
depends=(
'qt5-base'
'qt5-declarative'
'qt5-graphicaleffects'
'qt5-multimedia'
'qt5-quickcontrols'
'qt5-webkit'
'qt5-websockets'
'qt5-x11extras'
'mlt-git'
'ffmpeg'
'libx264'
'libvpx'
'lame'
'frei0r-plugins'
'ladspa'
)
makedepends=('git')
provides=('shotcut')
conflicts=('shotcut')
source=(
"${srcname}::git+https://github.com/mltframework/shotcut.git"
'shotcut.desktop'
'melt.patch'
)
sha512sums=(
'SKIP'
'SKIP'
'SKIP'
)
pkgver() {
cd "${srcdir}/${srcname}"
printf 'r%s.%s.%s\n' \
"$( git rev-list --count 'HEAD' )" \
"$( git log --max-count='1' --pretty='format:%ct' )" \
"$( git rev-parse --short 'HEAD' )"
}
prepare() {
cd "${srcdir}/${srcname}"
git apply "${srcdir}/melt.patch"
qmake PREFIX='/usr/'
}
build() {
cd "${srcdir}/${srcname}"
make
}
package() {
cd "${srcdir}/${srcname}"
make INSTALL_ROOT="${pkgdir}" install
install -D --mode=644 "${srcdir}/shotcut.desktop" "${pkgdir}/usr/share/applications/shotcut.desktop"
}
|