blob: 25a629201d059c7f0c1fcf7d213c0b82d50d91a1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: tarball <bootctl@gmail.com>
# Contributor: Claudia Pellegrino <aur ät cpellegrino.de>
# Contributor: Dmitriy Morozov <archlinux@foxcub.org>
pkgname=shpool
pkgver=0.8.0
pkgrel=1
pkgdesc='Think tmux, then aim... lower'
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url='https://github.com/shell-pool/shpool'
license=(Apache-2.0)
depends=('glibc' 'gcc-libs')
makedepends=('cargo')
checkdepends=('fish' 'less' 'zsh' 'procps-ng')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('6033b861c8da3325e44bd24acc5b3bd575281c97a3d1cfbcf9c89f3f1e1336c8c92d88a6b09c8a35cf61748e1c7667784b8c2162ac051406a045dd320b1c91c4')
build() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd $pkgname-$pkgver
cargo build --release --locked
}
check() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
export XDG_RUNTIME_DIR="${XDG_RUNTIME_DIR:-$PWD/test-run}"
cd $pkgname-$pkgver
cargo test --locked
}
package() {
cd $pkgname-$pkgver
install -Dm755 "target/release/$pkgname" \
"$pkgdir/usr/bin/$pkgname"
install -Dm644 README.md -t \
"$pkgdir/usr/share/doc/$pkgname/"
install -Dm644 systemd/shpool.{service,socket} -t \
"$pkgdir/usr/lib/systemd/user/"
}
|