summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7ce3a2677a0cc6782e262beef5440043ed2f4e44 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Contributor: runningdroid <runningdroid AT zoho.com.
# Contributor: sudokode <sudokode@gmail.com>
# Contributor: jsteel <mail at jsteel dot org>
# Contributor: Christoph Zeiler <rabyte*gmail>

pkgname=sidplay2-libs
pkgver=2.1.1
pkgrel=7
pkgdesc="The new generation of SID emulation"
arch=('i686' 'x86_64')
url="http://sidplay2.sourceforge.net"
license=('GPL')
depends=('gcc-libs')
makedepends=('pkgconfig' 'libtool' 'autoconf' 'automake')
options=('!emptydirs')
source=(http://downloads.sourceforge.net/sidplay2/sidplay-libs-$pkgver.tar.gz
        $pkgname.patch)
sha1sums=('8af6350866edc30b0d331e075fa97292f6f645a5'
          'e2d1fe7ddd53b3f614d8ab2740ab0af20dd72abb')

prepare() {
  cd "$srcdir"/sidplay-libs-$pkgver

  # fix bug #64
  sed -i -e 's|${libdir}/libsidplay2.la|-L${libdir} -lsidplay2|' libsidplay/unix/libsidplay2.pc.in
  sed -i -e 's|${libdir}/libsidutils.la|-L${libdir} -lsidutils|' libsidutils/unix/libsidutils.pc.in

  patch -Np1 -i "$srcdir"/$pkgname.patch
  autoreconf -i
}

build() {
  cd "$srcdir"/sidplay-libs-$pkgver
  export CXXFLAGS+=" -fPIC"

  ./configure --prefix=/usr

  make
}

package() {
  cd "$srcdir"/sidplay-libs-$pkgver

  make DESTDIR="$pkgdir" install
}