blob: 65964d5920182ce86ed450bccfa8e908eb26d5d6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: Eli Schwartz <eschwartz93@gmail.com>
# Contributor: David Mougey <imapiekindaguy at gmail dot com>
# All my PKGBUILDs are managed at https://github.com/eli-schwartz/pkgbuilds
# Set this variable to anything to disable translations.
# Or specify the two-letter language code of the translation you wish to keep.
_localepurge=
pkgname=sigil-git
pkgver=0.9.6.r23.g8e6b153
pkgrel=1
pkgdesc="A WYSIWYG ebook editor"
arch=('i686' 'x86_64')
url="https://github.com/Sigil-Ebook/Sigil"
license=('GPL3')
depends=('qt5-webkit' 'hunspell' 'minizip' 'python-lxml' 'python-six')
makedepends=('git' 'qt5-tools' 'qt5-svg' 'cmake')
optdepends=('hunspell-en: for English dictionary support'
'hyphen-en: for English hyphenation support in plugins'
'python-html5lib: recommended for plugins'
'python-chardet: recommended for plugins'
'python-cssselect: recommended for plugins'
'python-cssutils: recommended for plugins'
'python-pillow: recommended for plugins'
'python-regex: recommended for plugins')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("${pkgname%-git}"::"git+${url}")
sha256sums=('SKIP')
prepare() {
cd "${srcdir}/${pkgname%-git}"
if [[ "${_localepurge}" != "" ]]; then
for trans in src/Resource_Files/ts/*; do
if [[ "$(basename $trans | sed -r 's/(_.*)_.*/\1/g')" != "sigil_${_localepurge}" ]]; then
rm $trans
fi
done
fi
}
pkgver() {
cd "${srcdir}/${pkgname%-git}"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
mkdir -p "${srcdir}/${pkgname%-git}/build"
cd "${srcdir}/${pkgname%-git}/build"
cmake -G "Unix Makefiles" \
-DUSE_SYSTEM_LIBS=1 \
-DSYSTEM_LIBS_REQUIRED=1 \
-DINSTALL_BUNDLED_DICTS=0 \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_C_FLAGS:STRING="${CFLAGS}" \
-DCMAKE_CXX_FLAGS:STRING="${CXXFLAGS}" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_SKIP_RPATH=ON ..
make
}
package() {
cd "${srcdir}/${pkgname%-git}/build"
make install DESTDIR="${pkgdir}"
for _pic in 16 32 48 128 256; do
install -D -m 0644 ../src/Resource_Files/icon/app_icon_${_pic}.png \
"${pkgdir}"/usr/share/icons/hicolor/${_pic}x${_pic}/apps/sigil.png
done
# Compile python bytecode
python -m compileall "${pkgdir}"/usr/share/sigil/{plugin_launchers/python/,python3lib}
python -O -m compileall "${pkgdir}"/usr/share/sigil/{plugin_launchers/python/,python3lib}
}
|