blob: d76dd17c9b32157f5d293e634384b92824d43780 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: peeweep <peeweep at 0x0 dot ee>
pkgname=sigma
pkgver=0.14
pkgrel=1
pkgdesc="Generic Signature Format for SIEM Systems"
arch=('any')
url="https://github.com/Neo23x0/sigma"
license=('LGPL3')
depends=('python-yaml' 'python-argparse' 'python-urllib3' 'python-pymisp')
makedepends=('python-setuptools')
source=(
"${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz"
"pymisp.patch"
)
sha256sums=('0b14552591dc6a976861d403597da194e57b16ac90dd5d728709b1538efe8122'
'f6489322336e0e72d967fd22be157365676626a27e1f7da19df88d9efeff2eb7')
prepare() {
cd "${pkgname}-${pkgver}"/tools
patch -p1 <"${srcdir}/pymisp.patch"
}
build() {
cd "${pkgname}-${pkgver}"/tools
python setup.py build
}
package() {
cd "${pkgname}-${pkgver}"/tools
python setup.py install --root="${pkgdir}" --skip-build
mv "${pkgdir}/usr/etc/" "${pkgdir}"
# Update License
install -Dm 644 "${srcdir}/${pkgname}-${pkgver}/LICENSE.LGPL.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim: ts=2 sw=2 et:
|