PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

# Maintainer: David Birks <david@tellus.space>
# Maintainer: Jake <aur@ja-ke.tech>
# Contributor: Jonas Heinrich <onny@project-insanity.org>
# Contributor: Alda <alda@leetchee.fr>
# Contributor: mrxx <mrxx at cyberhome dot at>
# Contributor: Jonhoo <jon at thesquareplanet.com>
# Contributor: torvic9 <vic999 at mailbox.org>

pkgname=signal
pkgver=1.27.4
pkgrel=2
license=('GPL3')
pkgdesc='Private messenger for the desktop'
depends=('electron' 'openssl-1.0')
makedepends=('python' 'python2' 'npm' 'yarn' 'git' 'nodejs>=12')
conflicts=('signal-desktop-beta-bin' 'signal-desktop-bin')
arch=('i686' 'x86_64')
url='https://github.com/signalapp/Signal-Desktop'
source=("${pkgname}-git-repo::git+https://github.com/signalapp/Signal-Desktop.git#tag=v${pkgver}"
        "${pkgname}.sh"
        "${pkgname}.desktop"
        "${pkgname}-tray.desktop"
        "openssl-linking.patch")
sha512sums=('SKIP'
            '3525e8c0090feb7ea40a9a070bb5a089c0564346a88c7f8fbff1c6f7c779a24d9d77bdd43ad5a4dfd677fdaa4ad3cbd9b9a65e26bd1ff9453ba13b7dd95317a1'
            'a264bfc7a4a7aac747daa588a2acbf1eddfd201bc795f0fbc18460a9b25f4460f364124e227a527fec22631cd84bc9e190f9f4978069e9c119eb556b9ff2d327'
            'ced228d19303abe951c55f7874004cb9e4cd062dbda48c7ea80b0a6fb9adf5716a37164c01c9921a91f00653b0737fed80e3c5e684b0f3bcec375c265d6d8e5c'
            '05efc65a78b2006f3ffdd728dd5a96923ee9c909a3707833f8d55935c18e507051aabdbefff270bb2c58d7f151147966b550c9bbc2a115dae177f51955720482')

prepare() {
  cd "${pkgname}-git-repo"
  
  # Set system electron version
  _installed_electron_version=$(pacman -Q electron | cut -d' ' -f2 | cut -d'-' -f1)
  sed -E -i 's/"electron": "[0-9.]+"/"electron": "'$_installed_electron_version'"/' package.json

  # Allow higher node versions
  sed -i 's/"node": "/&>=/' package.json

  # Download modules
  yarn install

  # Use dynamic linking
  patch -Np1 -i "../openssl-linking.patch"
}

build() {
  cd "${pkgname}-git-repo"

  # Build Signal
  yarn generate
  yarn build-release --dir
}

package() {
  cd "${pkgname}-git-repo"

  install -dm 755 "${pkgdir}/usr/lib/${pkgname}"
  cp -r release/linux-unpacked/resources "${pkgdir}/usr/lib/${pkgname}/"

  for i in 16 24 32 48 64 128 256 512; do
    install -Dm 644 build/icons/png/${i}* "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/${pkgname}.png"
  done

  install -Dm 755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}-desktop"

  install -Dm 644 "${srcdir}"/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop
  install -Dm 644 "${srcdir}"/${pkgname}-tray.desktop "${pkgdir}"/usr/share/applications/${pkgname}-tray.desktop
}