blob: 071a804650230b6ee4ef6145555c2c24d2c96303 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
# Contributor: Jean Lucas <jean@4ray.co>
# This package is just an adaptation of the signal-desktop package
# that is in the official repos in order to provide a beta version
# of signal that does not use precompiled binaries.
# AUR Maintainer: Eduard Tolosa <edu4rdshl@protonmail.com>
pkgname=signal-desktop-beta
_pkgname=Signal-Desktop
pkgver=5.12.0beta2
pkgrel=2
pkgdesc="Signal Private Messenger for Linux"
license=('GPL3')
conflicts=('signal-desktop-beta-bin')
arch=('x86_64')
url="https://signal.org"
depends=('gtk3' 'libvips' 'libxss' 'hicolor-icon-theme')
makedepends=('yarn' 'git' 'nodejs-lts-fermium' 'npm6' 'python' 'git-lfs')
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/signalapp/${_pkgname}/archive/v${pkgver//beta*}-beta.${pkgver##*beta}.tar.gz"
"${pkgname}.desktop"
"expire-from-source-date-epoch.patch"
)
sha512sums=('f14dbec3ce35f2e0517e42cf5776736a398388ee96cb923250e38ba640c52f498580515afbb559eaa0932935f962e85eee45a15168650de4ee6cfc77a4c66e2d'
'b92c877f6673b3eaae94ca5623ab92f0e5676d439aaf7dc7424ce74f5a5786d30886e0b1013f0ef68a4ced53cdd16a2f78df8f1e41c039d61a980edf678f3e70'
'6673066172d6c367961f3e2d762dd483e51a9f733d52e27d0569b333ad397375fd41d61b8a414b8c9e8dbba560a6c710678b3d105f8d285cb94d70561368d5a2')
prepare() {
cd "${_pkgname}-${pkgver//beta*}-beta.${pkgver##*beta}"
git lfs install
# Allow higher Node versions
sed 's#"node": "#&>=#' -i package.json
# Select node-gyp versions with python3 support
sed 's#"node-gyp": "5.0.3"#"node-gyp": "6.1.0"#' -i package.json
# https://github.com/sass/node-sass/pull/2841
# https://github.com/sass/node-sass/issues/2716
sed -r 's#("resolutions": \{)#"resolutions": {"node-sass/node-gyp": "^6.0.0",#' -i package.json
yarn install --ignore-engines
# We can't read the release date from git so we use SOURCE_DATE_EPOCH instead
patch --forward --strip=1 --input="${srcdir}/expire-from-source-date-epoch.patch"
}
build() {
cd "${_pkgname}-${pkgver//beta*}-beta.${pkgver##*beta}"
yarn generate
yarn prepare-beta-build
yarn build
}
package() {
cd "${_pkgname}-${pkgver//beta*}-beta.${pkgver##*beta}"
install -d "${pkgdir}/usr/"{lib,bin}
cp -a release/linux-unpacked "${pkgdir}/usr/lib/${pkgname}"
ln -s "/usr/lib/${pkgname}/${pkgname}" "${pkgdir}/usr/bin/"
chmod u+s "${pkgdir}/usr/lib/${pkgname}/chrome-sandbox"
install -Dm 644 "../${pkgname}.desktop" -t "${pkgdir}/usr/share/applications"
for i in 16 24 32 48 64 128 256 512 1024; do
install -Dm 644 "build/icons/png/${i}x${i}.png" \
"${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/${pkgname}.png"
done
}
|